Lismo Sample Codes

Hello, World

[$hello_world]
hello_world {
    ド; レ; ミ;
}
君が代

[ 
    $right(inst:reed_organ, volume:0.2, oct:5) 
    $left(inst:reed_organ, oct:3)
    $vocal(oct:4)
]

vocal{
    R;
    レき; ドみ; レが; ミあ; ソよ; ミお; レ2わ;

    ミち; ソよ; ラに; ソ0.5い; ラ0.5い; レ>や; シち; ラよ; ソに;

    ミさ; ソざ; ラ2れ; レ>い; ド>し; レ>2の;

    ミい; ソわ; ラお; ソと; ミ1.5な; ソ0.5り; レ2て;
    
    ラこ; ド>け; レ>2の; ド>む; レ>う; ラす; ソう; ラま; ソ0.5あ; ミ0.5あ; レ2で; R2;
}

right{
    R;
    //君が代は
    レ; ド; レ; ミ; ソ; ミ; レ2;

    //千代に八千代に
    ミ; ソ; ラ; ソ0.5; ラ0.5; レ>; シ; ラ; ソ;

    //さざれ石の
    ミ; ソ; ラ2; [ファ;レ>;] [ミ;ド>;] [ファ;レ>2;]

    //巌となりて
    ミ; ソ; ラ; ソ; ミ1.5; ソ0.5; レ2;
    
    //苔のむすまで
    [ファ;ラ;] [ファ;ラ;ド>;] [ファ;ラ;レ>2;] ド>; レ>; ラ; ソ; ラ; ソ0.5; ミ0.5; レ2; R2;
}

left{
    R;
    //君が代は
    レ; ド; レ; ミ; ソ; ミ; レ2;

    //千代に八千代に
    ド; ミ; ファ; ミ0.5; ファ0.5; ファ+; ソ; レ0.5; レ0.5; ミ;

    //さざれ石の
    ド; ミ; ファ2; レ; ラ<; レ2;

    //巌となりて
    ド; ミ; ファ; ミ; ド; ミ; ソ<; ソ;
    
    //苔のむすまで
    ファ; ファ; ファ2; ラ<; レ; ラ; ソ; ラ; ソ0.5; ミ0.5; レ2; R2;
}
Lemon

[ $main(tempo: 360, inst:glockenspiel, volume:0.5, oct:5) ]

main{
    $sub1 $sub2 $sub1 $sub3 休6; $sub1 $sub2 $sub1 $sub3
    $sub4 $sub5 $sub5 $sub6 $sub5 $sub7 $sub9 $sub10
}

sub1{
    シ; ド>+; レ>+2; シ; ソ+3; 
    ド>+2; ラ+2; ファ+; レ+3;
    ラ+2; ソ+2; ファ+; シ<3; ファ+2; レ+4; 休2;
}

sub2{
    ド+; レ+; ミ4; シ2; ラ+; シ; ファ+4; ミ2; レ+; ミ; ファ3;
    ファ; シ2; ラ+; ソ+; ソ4; 休2;
}

sub3{
    ド+; レ+; ミ4; ファ+2; ミ; ファ+; レ+2; ファ+2; シ2; レ>+2;
    ド>+3; ド>+; ド>+; シ2; シ; シ8;
}

sub4{
    ソ+2; 休; ラ+; シ2; ラ+; ソ+; ファ+2; レ>+2; レ>+4;
    ド>+3; レ>+; ミ>2; レ>+; ド>+; シ2; ド>+2; ファ+4;
    ミ3; ファ+; ソ+2; ファ+; ミ; レ+2; シ2; シ2; シ2; ラ+4; ソ+2; ラ+2; シ4;
}

sub5{
    ド>+; レ>+; ド>+; シ; ソ+; シ3; レ>+; ファ>+3; ド>+; シ3;
}

sub6{
    ド>+; レ>+; ド>+; シ; ソ+; シ3; レ>+; ファ>+2; ファ>+; ソ>+; ファ>+3;
    ファ>+; シ>3; ラ>+; ファ>+3; レ>+; ファ>+2; ド>+; ド>+4;
}

sub7{
    シ; ド>+; レ>+; ミ>; レ>+3; ド>+; ラ+3; シ4; 休2;
}

sub8{
    シ; ラ+; ソ+2; ラ+2; シ2; ド>+2; シ2; ファ+2;
}

sub9{
    $sub8 レ+; ファ+3; ソ+; ド>+3; ラ+; シ3; シ4; 休2;
}

sub10{
    $sub8 シ; ド>+3; レ>+; ミ>3; ド>+; シ3; シ4; 休4;
}
きらきら星

[
    $right(tempo:90, inst:horn)
    $left(tempo:45, inst:horn, volume:0.5, oct:3)
]

right{
    $r1 $r2 $r3 $r3 $r1 $r2
}
r1{
    C; C; G; G; A; A; G2;
}
r2{
    F; F; E; E; D; D; C2;
}
r3{
    G; G; F; F; E; E; D2;
}

left{
    $l1 $l2 $l3 $l3 $l1 $l2
}
l1{
    [C; E; G;] [C; E; G;] [C; F; A;] [C; E; G;]
}
l2{
    [B<; D; G;] [C; E; G;] [B<; D; G;] [C; E; G;]
}
l3{
    [C; E; G;] [B<; D; G;] [C; E; G;] [B<; D; G;]
}